SQL Server如何用觸發器捕獲DML操作的會話資訊

原文: SQL Server如何用觸發器捕獲DML操作的會話資訊

需求背景

    上周遇到了這樣一個需求，維護人員發現一個表的資料經常被修改，由于曆史原因；文檔缺少；以及維護人員的經常變更，導緻他們對系統也業務也不完全熟悉，他們也不完全清楚哪些系統和應用程式會對這個表的資料進行操作。現在他們想找出有哪些伺服器，哪些應用程式會對這個表進行INSERT、UPDATE操作。那麼問題來了，怎麼去解決這個問題呢？

解決方案

由于資料庫版本是标準版，我們選擇了使用觸發器來捕獲進行DML操作的會話的相關資訊，例如，Host_Name、Program_Name等 ，選擇觸發器是因為簡單直接。我們先建立一個表名為TEST的表，假設我們想監控有哪些應用伺服器，以及那些應用程式會對表TEST進行INSERT、UPDATE操作。

USE [AdventureWorks2014]      

GO      

IF NOT EXISTS (SELECT 1 FROM sys.sysobjects WHERE id=object_id(N'[dbo].[TEST]') AND OBJECTPROPERTY(id, N'IsTable')=1 )      

BEGIN      

CREATE TABLE [dbo].[TEST](      

    [OBJECT_ID] [INT] NOT NULL,      

    [NAME] [VARCHAR](8) NULL,      

    CONSTRAINT PK_TEST    PRIMARY KEY (OBJECT_ID)      

)       

END      

GO      

INSERT INTO dbo.TEST      

SELECT 1, 'kerry' UNION ALL      

SELECT 2, 'jimmy'      

那麼我們接下來在表上面新增幾個字段 [HOST_NAME]、[PROGRAM_NAME]、LOGIN_NAME用來記錄最後一次修改該記錄的會話資訊，另外建立觸發器TRG_TEST來更新這幾個字段

ALTER TABLE TEST ADD  [HOST_NAME]  NVARCHAR(256)      

ALTER TABLE TEST ADD  [PROGRAM_NAME] NVARCHAR(256);      

ALTER TABLE TEST ADD  LOGIN_NAME  NVARCHAR(256);      

CREATE TRIGGER TRG_TEST ON dbo.TEST AFTER       

INSERT,UPDATE      

AS       

IF (EXISTS(SELECT  1 FROM  INSERTED))      

BEGIN      

    UPDATE  dbo.TEST      

    SET     dbo.TEST.[HOST_NAME] = ( SELECT host_name      

                                     FROM   sys.dm_exec_sessions      

                                     WHERE  session_id = @@SPID      

                                   ) ,      

            dbo.TEST.PROGRAM_NAME = ( SELECT    program_name      

                                      FROM      sys.dm_exec_sessions      

                                      WHERE     session_id = @@SPID      

                                    ) ,      

            dbo.TEST.LOGIN_NAME = ( SELECT  login_name      

                                    FROM    sys.dm_exec_sessions      

                                    WHERE   session_id = @@SPID      

                                  )      

    FROM    dbo.TEST t      

            INNER JOIN INSERTED i ON t.OBJECT_ID = i.OBJECT_ID      

END      

GO      

接下來，我們來簡單測試一下，如下所示，分布插入、更新一條記錄

INSERT INTO dbo.TEST(OBJECT_ID,NAME)      

SELECT 3,'ken'      

UPDATE dbo.TEST SET NAME='Richard' WHERE  OBJECT_ID=2;      

如下所示，因為我隻是用SSMS更新，插入資料，是以捕獲的是Microsoft SQL Server Management Studio - Query。

http://images2015.cnblogs.com/blog/73542/201703/73542-20170320155027033-2023769308.png

這這種方式還有一個弊端，那就是如果應用程式的SQL，寫得不夠健壯的話，那麼增加字段就會導緻以前的應用程式出現問題，例如，應用程式有下面這樣的SQL，增加字段後，它就會報錯。

INSERT INTO dbo.TEST      

SELECT 3,'ken'      

是以這種方案不太可行，會增加應用程式出現Bug的風險。那麼其實我們可以建立一個表，每當原表TEST有INSERT、UPDATE操作時，通過觸發器捕獲會話程序資訊，然後插入該表（注意，建立的表包含源表的主鍵字段，例如這裡TEST的主鍵字段為OBJECT_ID，那麼我們下面就包含OBJECT_ID）

USE [AdventureWorks2014]      

GO      

DROP TABLE  dbo.[TRG_TEST_SESSION_INFO];      

GO      

IF NOT EXISTS (SELECT 1 FROM sys.sysobjects WHERE id=object_id(N'[dbo].[TRG_TEST_SESSION_INFO]') AND OBJECTPROPERTY(id, N'IsTable')=1 )      

BEGIN      

CREATE TABLE [TRG_TEST_SESSION_INFO](      

    [ID]               INT NOT NULL IDENTITY(1,1),      

    [OBJECT_ID]        INT,      

    [HOST_NAME]        NVARCHAR(256),      

    [PROGRAM_NAME]     NVARCHAR(256),      

    [LOGIN_NAME]       NVARCHAR(256),      

    CONSTRAINT PK_TRG_TEST_SESSION_INFO    PRIMARY KEY (ID)      

)       

END      

GO      

CREATE TRIGGER TRG_TEST_SESSION ON dbo.TEST      

AFTER INSERT ,UPDATE      

AS      

IF (EXISTS(SELECT  1 FROM  INSERTED))      

BEGIN      

    /*      

    INSERT INTO dbo.[TRG_TEST_SESSION_INFO]      

    SELECT  (SELECT I.OBJECT_ID FROM INSERTED I), HOST_NAME,program_name,login_name      

                                     FROM   sys.dm_exec_sessions      

                                     WHERE  session_id = @@SPID*/      

    INSERT INTO dbo.[TRG_TEST_SESSION_INFO]      

    SELECT  I.OBJECT_ID, S.HOST_NAME,S.PROGRAM_NAME,S.LOGIN_NAME      

                                     FROM   sys.dm_exec_sessions s,      

                                            Inserted i      

                                     WHERE  session_id = @@SPID      

END      

GO      

在運作一小段時間後，如果已經找出了哪些伺服器、哪些應用程式會對這些表操作後，那麼就必須馬上删除這些表和觸發器，避免長時間運作，影響性能。