Groovy与Java的不同点

本文参考自 Groovy文档 Differences with Java

，所有代码都是Groovy文档中的，也可以将本文看做英文源文档的简略翻译。

Groovy设计时目标之一就是让Java程序员快速习惯Groovy。不过在Groovy中也有很多地方和Java不相同。列举如下。

默认导入

下面这些包会由Groovy默认导入，我们不需要手动导入这些包就可以直接使用其中的类。

• java.io.*
• java.lang.*
• java.math.BigDecimal
• java.math.BigInteger
• java.net.*
• java.util.*
• groovy.lang.*
• groovy.util.*

多方法

Groovy的方法调用时机在运行时决定，这叫做运行时分发或者多方法。下面是一个例子。

int method(String arg) {
    return 1;
}
int method(Object arg) {
    return 2;
}
Object o = "Object";
int result = method(o);
           

在Java中下面的断言是成功的。

assertEquals(2, result);
           

在Groovy中下面的断言是成功的。

assertEquals(1, result);
           

在Java中由于方法调用时编译期决定的，而o的类型是Object，所以会返回2。而Groovy是在运行时决定方法调用的，由于对象的实际类型是字符串，所以会返回1。

数组初始化

由于在Groovy中花括号用作闭包声明，因此数组初始化需要使用方括号。

//java中合法，Groovy不能
int[] array = { 1, 2, 3}

//Groovy正确的声明方式
int[] array = [1,2,3]
           

包访问权限

在Java中不带访问修饰符的字段默认是包可见的。在Grooy中默认是私有的。如果希望在Groovy中设置包访问权限。可以使用@PackageScope注解。

class Person {
    @PackageScope String name
}
           

自动资源管理

Java7中引入了自动资源管理功能，可以以较简便的方式打开和释放资源。在Groovy中，闭包让这些工作更简单。下面是一段Java代码。

Path file = Paths.get("/path/to/file");
Charset charset = Charset.forName("UTF-8");
try (BufferedReader reader = Files.newBufferedReader(file, charset)) {
    String line;
    while ((line = reader.readLine()) != null) {
        System.out.println(line);
    }

} catch (IOException e) {
    e.printStackTrace();
}
           

对应的Groovy代码非常简单。

new File('/path/to/file').eachLine('UTF-8') {
   println it
}
           

或者还可以使用折中方式。

new File('/path/to/file').withReader('UTF-8') { reader ->
   reader.eachLine {
       println it
   }
}
           

Lambda

Java 8 支持Lambda表达式，不过Groovy不支持。Groovy支持闭包。

Runnable run = () -> System.out.println("Run");
list.forEach(System.out::println);
           

对应的Groovy代码。

Runnable run = { println 'run' }
list.each { println it } // or list.each(this.&println)
           

GString

Groovy通过GString来支持内插字符串。如果在单引号字符串中发现

${}

，会发生编译错误。另外Groovy可以自动将GString转换为String，所以我们可以放心的引用各种Java类库。

字符串和字符常量

Groovy中单引号用作字符串常量，所以我们没办法声明一个字符常量。如果需要单个字符，我们必须显式声明一个字符变量，然后用单引号将字符赋给它。

char a='a'
           

对于字符串和字符之间的转换，也有两种方式：Groovy的as运算符和传统的Java转换方式。但是假如单引号之间是一个字符串，这两种转换方式就不一样了。Java转换会抛出异常，而Groovy方式会获取字符串的第一个字母作为转换后的字符。

// for single char strings, both are the same
assert ((char) "c").class==Character
assert ("c" as char).class==Character

// for multi char strings they are not
try {
  ((char) 'cx') == 'c'
  assert false: 'will fail - not castable'
} catch(GroovyCastException e) {
}
assert ('cx' as char) == 'c'
assert 'cx'.asType(char) == 'c'
           

基本类型和包装器

Groovy是完全对象化的，所以所有基本类型都会转换为其包装器来使用。Groovy不支持Java的扩宽优先于包装器的规则。因此下面的代码，在Java中会执行第一个m方法，在Groovy中会执行第二个m方法。

int i
m(i)

void m(long l) {           
  println "in m(long)"
}

void m(Integer i) {        
  println "in m(Integer)"
}
           

相等运算符的行为

Java中

==

会比较对象引用是否是同一个。而在Groovy中，如果对象实现了

Comparable

，就会调用

a.compareTo(b)==0

方法；如果没有实现，则调用

a.equals(b)

。如果需要判断对象引用，可以使用is函数，

a.is(b)

。

额外的关键字

在Groovy中，

def

、

as

in

trait

都是关键字，不要将它们用作变量名等等。