Android 屏幕录制GIF脚本

image.png

因为一直需要将Android手机上的效果录制下来，转成gif，然后上传到博客上。

原来都需要手动操作好几次，所以索性的写了一个脚本来配合使用。

环境准备

FFmpeg下载

去官网下载地址下载好，解压就可以了。
adb下载

需要下载AndroidSDK。因为笔者下载了Android Studio,帮忙下好SDK。所以就不过多描述了。

脚本书写

关键的几个指令

0.adb截屏

adb shell screencap -p /sdcard/screencap.png

复制

adb录屏

--time-limit 参数是限定时间的长短

F:\AndroidSDK\platform-tools\adb shell screenrecord  --time-limit %t% /sdcard/demo.mp4

复制

pull到电脑上

F:\AndroidSDK\platform-tools\adb pull /sdcard/demo.mp4

复制

ffmpeg 命令转成gif

F:\ffmpeg-20171128-86cead5-win64-static\ffmpeg-20171128-86cead5-win64-static\bin/ffmpeg -i demo.mp4 -s 360x640 -r 10 target-%dh%.gif

复制

修改视频的尺寸

-s 参数是修改视频的尺寸。因为原来截屏的尺寸上传太大了。所以缩小。

注意：这个尺寸需要根据手机的分辨率来确定。我的手机分辨率是1080x1920。所以这些缩小成360x640
缩小gif的大小

-r 指令是修改gif的帧率。这样能适当的缩小转出来的gif大小
剪切视频尺寸

-vf crop=width:height:x:y

ffmpeg -i 视频源地址 -strict -2 -vf crop=1080:1080:0:420 视频输出地址（如：out.mp4）

复制

其中的 crop=1080:1080:0:420 才裁剪参数，具体含义是，其中 width 和 height 表示裁剪后的尺寸，x:y 表示裁剪区域的左上角坐标。比如当前这个示例，我们只需要保留竖向视频的中间部分，所以 x 不用偏移，故传入0，而 y 则需要向下偏移：(1920 – 1080) / 2 = 420

完整的脚本

windows

@echo off
set /p t=请输入录制时间s:
rem 开始录制
adb shell screenrecord  --time-limit %t% /sdcard/demo.mp4
adb pull /sdcard/demo.mp4
set h=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%
set dh=%h: =0%
rem ffmpeg转换
F:\ffmpeg-20171128-86cead5-win64-static\ffmpeg-20171128-86cead5-win64-static\bin/ffmpeg -i demo.mp4 -s 360x640 -r 10 target-%dh%.gif
rem 删除缓存的视频
del demo.mp4
rem 直接打开我们最后的gif
start target-%dh%.gif

复制

另外一个可以剪切尺寸的

@Echo off&setlocal,EnableDelayedExpansion

set /p duration=请输入录制时间(秒):
set h=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%
set dh=%h: =0%

:isCrop
set /p isCrop=是否需要裁剪(y/n):
IF /i "!isCrop!"=="Y" (
    set /p cropHeight= 输入裁剪的高度:
    rem /a表示进行数值运算
    set /A convertHeight=!cropHeight!/3
    Echo !convertHeight!  , cropHeight =!cropHeight!

    Echo 开始录制
    adb shell screenrecord  --time-limit %duration% /sdcard/demo.mp4
    adb pull /sdcard/demo.mp4
    Echo ffmpeg转换
    F:\ffmpeg-20171128-86cead5-win64-static\ffmpeg-20171128-86cead5-win64-static\bin/ffmpeg -i demo.mp4 -vf crop=1080:!cropHeight!:0:0 -s 360x!convertHeight! -r 10 target-%dh%.gif
)else (
    Echo 开始录制
    adb shell screenrecord  --time-limit %duration% /sdcard/demo.mp4
    adb pull /sdcard/demo.mp4
    Echo ffmpeg转换
    F:\ffmpeg-20171128-86cead5-win64-static\ffmpeg-20171128-86cead5-win64-static\bin/ffmpeg -i demo.mp4 -s 360x640 -r 10 target-%dh%.gif
)
Echo 删除缓存的视频
del demo.mp4
Echo 直接打开我们最后的gif
start target-%dh%.gif

复制

附带一个截屏的脚本

@Echo off
set h=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%
set dh=%h: =0%
echo 正在截屏
adb shell screencap -p /sdcard/screencap.png
adb pull /sdcard/screencap.png
ren  screencap.png screencap-%dh%.png
echo 完成关闭

复制

最后主要注意编码问题，请选择脚本的编码为GBK。以免出现中文乱码的问题

保存成

.bat

文件，这样双击就能运行，然后就可以愉快的得到gif了。

Linux/Mac

#!/bin/bash
echo -e '请输入录制时间:'
read t
echo -e '开始录制' 
adb shell screenrecord  --time-limit $t /sdcard/demo.mp4
adb pull /sdcard/demo.mp4 

# # 获取时间戳
currentTimeStamp=$(date +%s)
echo $currentTimeStamp

#'ffmpeg转换' 
ffmpeg -i demo.mp4 -s 360x640 -r 10 target-$currentTimeStamp.gif
#'删除缓存的视频' 
rm -f demo.mp4
# '输出打开我们最后的gif /r' 
echo "$(cd `dirname $0`; pwd)"/target-$currentTimeStamp.gif

复制

注意需要给脚本对应的权限。

保存成

.sh

文件,就可以运行，最后输出的就是文件所在的路径。