motor joint

昨天我们学习了 Box2D 的"距离关节"b2DistanceJoint ，并用它模拟了一个简单的自行车。今天我们来学习"马达关节" b2RevoluteJoint 。

"马达关节"b2RevoluteJoint同样连接了两个刚体bodyA和bodyB。不过和"马达关节"不同的是，它只有一个节点anchor，所以两个刚体都只能围绕这一个节点选择。另外，我们可以在这个节点anchor位置施加一个作用力maxMotorTorque，这样节点就会想马达一样转起来，所以我把它叫做"马达关节"。

还是不好理解，对吧！那就再打个比方，我把b2RevoluteJoint关节比作....电风扇。风扇叶是bodyA，马达是anchor，底座是bodyB，下面的图可以更好的解释这一点：

如上图所示，因为节点anchor在bodyA的圆心处，所以bodyA会围绕着节点anchor旋转。

b2RevoluteJoint的initialize方法结构如下：

1.     public function Initialize(
2.         bA:b2Body,
3.         bB:b2Body,
4.         anchor:b2Vec2
5.     ) : void

复制代码 bA即bodyA，bB即bodyB，anchor即节点，具体的功能，我在前面都讲过了，就不再赘述了。

另外，如前面提到的，通过设置b2RevoluteJointDef的maxMotorTorque、motorSpeed和enableMotor，可以模拟马达旋转。这三个参数的作用分别如下：

• enableMotor：决定是否使用
• motormotorSpeed：设置最大的角速度
• maxMotorTorque：要达到角速度应用的扭矩力这三个属性是让节点转起来的必要条件，缺一不可！记住哦。

用b2RevoluteJoint实现风扇的效果如下：

完整的代码和注释如下：

1. package
2. {
3.     import Box2D.Collision.Shapes.b2PolygonShape;
4.     import Box2D.Collision.Shapes.b2Shape;
5.     import Box2D.Common.Math.b2Vec2;
6.     import Box2D.Dynamics.b2Body;
7.     import Box2D.Dynamics.b2BodyDef;
8.     import Box2D.Dynamics.b2FixtureDef;
9.     import Box2D.Dynamics.b2World;
10.     import Box2D.Dynamics.Joints.b2RevoluteJoint;
11.     import Box2D.Dynamics.Joints.b2RevoluteJointDef;
12.     import flash.display.Sprite;
13.     import flash.events.Event;
14.     import flash.events.MouseEvent;
15.     import flash.geom.Point;
16.     public class RevoluteJointTest extends Sprite
17.     {
18.         private var world:b2World;
19.         private var debugSprite:Sprite;
20.         private var bodyA:b2Body, bodyB:b2Body;
21.         private var posA:Point, posB:Point;
22.         public function RevoluteJointTest()
23.         {
24.             LDEasyBox2D.stage = stage;
25.             world=LDEasyBox2D.createWorld();
26.             debugSprite=LDEasyBox2D.createDebug(world);
27.             addChild(debugSprite);
28.             //创建地面，
29.             LDEasyBox2D.createWrapWall(world, stage);
30.             createBodies();
31.             createRevoluteJoint();
32.             addEventListener(Event.ENTER_FRAME, loop);
33.             stage.addEventListener(MouseEvent.MOUSE_DOWN, onStageMouseDown);
34.             stage.addEventListener(MouseEvent.MOUSE_UP, onStageMouseUp);
35.         }
36.         private function createRevoluteJoint():void
37.         {
38.             //创建马达关节需求
39.             var revoluteJoint:b2RevoluteJointDef = new b2RevoluteJointDef();
40.             //用bodyA、bodyB和anchor节点初始化马达关节
41.             revoluteJoint.Initialize( bodyA, bodyB, new b2Vec2(posA.x / 30, posA.y / 30));
42.             //设置连接的两个刚体之间不进行碰撞检测
43.             revoluteJoint.collideConnected = false;
44.             //开启马达
45.             revoluteJoint.enableMotor = true;
46.             //设置马达的最大角速度，单位为 弧度/秒，如设置为Math.PI，即每秒钟转180度
47.             revoluteJoint.motorSpeed = Math.PI;
48.             //设置最大的扭力值
49.             revoluteJoint.maxMotorTorque = 500;
50.             //创建马达关节
51.             world.CreateJoint(revoluteJoint);
52.         }
53.         //创建bodyA和bodyB刚体
54.         private function createBodies():void
55.         {
56.             //设置两个刚体的坐标位置
57.             posA = new Point(275, 100);
58.             posB = new Point(275, 300);
59.             //创建一个十字刚体，赋值给bodyA
60.             var bodyDef:b2BodyDef = new b2BodyDef();
61.             bodyDef.type = b2Body.b2_dynamicBody;
62.             bodyDef.position.Set(posA.x / 30, posA.y / 30);
63.             bodyA = world.CreateBody(bodyDef);
64.             //设置刚体属性
65.             var fixtureDef:b2FixtureDef = new b2FixtureDef();
66.             fixtureDef.density = 3;
67.             fixtureDef.restitution = .2;
68.             fixtureDef.friction = .2;
69.             //设置刚体形状，并赋值给fixtureDef
70.             //一个横着的矩形
71.             var shape:b2PolygonShape = new b2PolygonShape();
72.             shape.SetAsBox(50/30, 5/30);
73.             fixtureDef.shape = shape;
74.             bodyA.CreateFixture(fixtureDef);
75.             //加一个竖着的矩形
76.             shape.SetAsBox(5 / 30, 50 / 30);
77.             fixtureDef.shape = shape;
78.             //生成刚体bodyA的形状
79.             bodyA.CreateFixture(fixtureDef);
80.             //创建bodyB刚体
81.             bodyB = LDEasyBox2D.createBox(world, posB.x, posB.y, 200, 50);
82.         }
83.         private function onStageMouseDown(e:MouseEvent):void
84.         {
85.             var dragBody:b2Body = LDEasyBox2D.getBodyAtMouse(world);
86.             if (dragBody != null) {
87.                 LDEasyBox2D.startDragBody(world,dragBody,10000*dragBody.GetMass());
88.             }
89.         }
90.         private function onStageMouseUp(e:MouseEvent):void
91.         {
92.             LDEasyBox2D.stopDragBody(world);
93.         }
94.         private function loop(e:Event):void
95.         {
96.             LDEasyBox2D.updateWorld(world);
97.         }
98.     }
99. }

复制代码 代码中用到了我写的静态类LDEasyBox2D，可以有效的简化代码，具体请参考 这里 。

点击刚体，还可以进行拖动，如果对鼠标拖动刚体，我建议你看看之前的 让刚体听我的——鼠标拖动刚体 。 

OK 2012-08-28 b2RevoluteJoint关节.rar (340.1 KB, 下载次数: 106)