请问批处理中符号%~nx0和!num!%%~xm表示什么意思呢?
@echo off
setlocal enableDelayedExpansion
for %%m in (*) do (
if not "%%m"=="%~nx0" (
set /a num+=1
ren "%%m" "!num!%%~xm"
)
)
echo 改名完毕!!!!
pause
以上代码中的 "%~nx0" 和 "!num!%%~xm"分别表示什么意思呢?
如何用code把代码扩起来
http://bbs.bathome.net/viewthread.php?tid=404&highlight=code
代码中"%~nx0" 表示批处理文件名及扩展名,也就是批处理本身,这一条代码表示防止对批处理本身重命名
"!num!%%~xm"表示 重命名后的文件名及扩展名(如1.txt)每循环一次!num!的值加1,其中一对!是在延迟变变量环境下的对变量的引用。
%~nI 只显示当前路径下所有文件的文件名(不显扩展名)和目录(没有的话就不显)
%~xI 只显示当前路径下所有文件的扩展名,若当前路径下有目录(文件夹)的话,就会出现 echo处于关闭状态
setlocal enableDelayedExpansion
开启延迟变量
for %%m in (*) do (
当运行了上面一句后(注意此时还没有运行do后面的命令),我们可以理解为for已经把当前目录下所有的文件都保存到了内存.(嘿嘿,上面的话,盗用随风大大的)
if not "%%m"=="%~nx0" (
为了避免对批处理本身改名,通过if判断%%m是否为批处理本身,其中%%m是要更改的文件,而"%~nx0" 表示批处理文件名及扩展名,也就是批处理本身
set /a num+=1
将sum的值加1,由于之前没有对num定义,所以num的值是空的,那么现在它的值是“空”+1,也就是num=1,
ren "%%m" "!num!%%~xm"
利用ren命令修改文件名。把"%%m"改名为"!num!%%~xm"。对于新文件名"!num!%%~xm",其中!num!表示文件名,也就是上面的1(每循环依次num的值加1),%%~xm表示文件的扩展名。
FOR 变量参照的替换已被增强。您现在可以使用下列
选项语法:
~I - 删除任何引号("),扩充 %I
%~fI - 将 %I 扩充到一个完全合格的路径名
%~dI - 仅将 %I 扩充到一个驱动器号
%~pI - 仅将 %I 扩充到一个路径
%~nI - 仅将 %I 扩充到一个文件名
%~xI - 仅将 %I 扩充到一个文件扩展名
%~sI - 扩充的路径只含有短名
%~aI - 将 %I 扩充到文件的文件属性
%~tI - 将 %I 扩充到文件的日期/时间
%~zI - 将 %I 扩充到文件的大小
%~$PATH:I - 查找列在路径环境变量的目录,并将 %I 扩充
到找到的第一个完全合格的名称。如果环境变量名
未被定义,或者没有找到文件,此组合键会扩充到
空字符串
可以组合修饰符来得到多重结果:
%~dpI - 仅将 %I 扩充到一个驱动器号和路径
%~nxI - 仅将 %I 扩充到一个文件名和扩展名
%~fsI - 仅将 %I 扩充到一个带有短名的完整路径名
%~dp$PATH:i - 查找列在路径环境变量的目录,并将 %I 扩充
到找到的第一个驱动器号和路径。
%~ftzaI - 将 %I 扩充到类似输出线路的 DIR
在以上例子中,%I 和 PATH 可用其他有效数值代替。%~ 语法
用一个有效的 FOR 变量名终止。选取类似 %I 的大写变量名
比较易读,而且避免与不分大小写的组合键混淆。