linux awk指令詳解

簡介

awk是一個強大的文本分析工具，相對于grep的查找，sed的編輯，awk在其對資料分析并生成報告時，顯得尤為強大。簡單來說awk就是把檔案逐行的讀入，以空格為預設分隔符将每行切片，切開的部分再進行各種分析處理。

awk有3個不同版本: awk、nawk和gawk，未作特别說明，一般指gawk，gawk 是 AWK 的 GNU 版本。

awk其名稱得自于它的創始人 Alfred Aho 、Peter Weinberger 和 Brian Kernighan 姓氏的首個字母。實際上 AWK 的确擁有自己的語言： AWK 程式設計語言，三位建立者已将它正式定義為“樣式掃描和處理語言”。它允許您建立簡短的程式，這些程式讀取輸入檔案、為資料排序、處理資料、對輸入執行計算以及生成報表，還有無數其他的功能。

使用方法

awk '{pattern + action}' {filenames}

盡管操作可能會很複雜，但文法總是這樣，其中 pattern 表示 AWK 在資料中查找的内容，而 action 是在找到比對内容時所執行的一系列指令。花括号（{}）不需要在程式中始終出現，但它們用于根據特定的模式對一系列指令進行分組。 pattern就是要表示的正規表達式，用斜杠括起來。

awk語言的最基本功能是在檔案或者字元串中基于指定規則浏覽和抽取資訊，awk抽取資訊後，才能進行其他文本操作。完整的awk腳本通常用來格式化文本檔案中的資訊。

通常，awk是以檔案的一行為處理機關的。awk每接收檔案的一行，然後執行相應的指令，來處理文本。

調用awk

有三種方式調用awk

1.指令行方式
awk [-F  field-separator]  'commands'  input-file(s)
其中，commands 是真正awk指令，[-F域分隔符]是可選的。 input-file(s) 是待處理的檔案。
在awk中，檔案的每一行中，由域分隔符分開的每一項稱為一個域。通常，在不指名-F域分隔符的情況下，預設的域分隔符是空格。

2.shell腳本方式
将所有的awk指令插入一個檔案，并使awk程式可執行，然後awk指令解釋器作為腳本的首行，一遍通過鍵入腳本名稱來調用。
相當于shell腳本首行的：#!/bin/sh
可以換成：#!/bin/awk

3.将所有的awk指令插入一個單獨檔案，然後調用：
awk -f awk-script-file input-file(s)
其中，-f選項加載awk-script-file中的awk腳本，input-file(s)跟上面的是一樣的。

　　本章重點介紹指令行方式。

入門執行個體

假設last -n 5的輸出如下

[root@www ~]# last -n 5 <==僅取出前五行
root     pts/1   192.168.1.100  Tue Feb 10 11:21   still logged in
root     pts/1   192.168.1.100  Tue Feb 10 00:46 - 02:28  (01:41)
root     pts/1   192.168.1.100  Mon Feb  9 11:41 - 18:30  (06:48)
dmtsai   pts/1   192.168.1.100  Mon Feb  9 11:41 - 11:41  (00:00)
root     tty1                   Fri Sep  5 14:09 - 14:10  (00:01)

　　如果隻是顯示最近登入的5個帳号

#last -n 5 | awk  '{print $1}'
root
root
root
dmtsai
root

　　awk工作流程是這樣的：讀入有'\n'換行符分割的一條記錄，然後将記錄按指定的域分隔符劃分域，填充域，$0則表示所有域,$1表示第一個域,$n表示第n個域。預設域分隔符是"空白鍵" 或 "[tab]鍵",是以$1表示登入使用者，$3表示登入使用者ip,以此類推。

如果隻是顯示/etc/passwd的賬戶

#cat /etc/passwd |awk  -F ':'  '{print $1}'  
root
daemon
bin
sys

這種是awk+action的示例，每行都會執行action{print $1}。

-F指定域分隔符為':'。

如果隻是顯示/etc/passwd的賬戶和賬戶對應的shell,而賬戶與shell之間以tab鍵分割

#cat /etc/passwd |awk  -F ':'  '{print $1"\t"$7}'
root    /bin/bash
daemon  /bin/sh
bin     /bin/sh
sys     /bin/sh

　　如果隻是顯示/etc/passwd的賬戶和賬戶對應的shell,而賬戶與shell之間以逗号分割,而且在所有行添加列名name,shell,在最後一行添加"blue,/bin/nosh"。

cat /etc/passwd |awk  -F ':'  'BEGIN {print "name,shell"}  {print $1","$7} END {print "blue,/bin/nosh"}'
name,shell
root,/bin/bash
daemon,/bin/sh
bin,/bin/sh
sys,/bin/sh
....
blue,/bin/nosh

linux awk指令詳解

awk工作流程是這樣的：先執行BEGING，然後讀取檔案，讀入有/n換行符分割的一條記錄，然後将記錄按指定的域分隔符劃分域，填充域，$0則表示所有域,$1表示第一個域,$n表示第n個域,随後開始執行模式所對應的動作action。接着開始讀入第二條記錄······直到所有的記錄都讀完，最後執行END操作。

搜尋/etc/passwd有root關鍵字的所有行

#awk -F: '/root/' /etc/passwd
root:x:0:0:root:/root:/bin/bash

這種是pattern的使用示例，比對了pattern(這裡是root)的行才會執行action(沒有指定action，預設輸出每行的内容)。

搜尋支援正則，例如找root開頭的: awk -F: '/^root/' /etc/passwd

搜尋/etc/passwd有root關鍵字的所有行，并顯示對應的shell

# awk -F: '/root/{print $7}' /etc/passwd             
/bin/bash

　　這裡指定了action{print $7}

awk内置變量

awk有許多内置變量用來設定環境資訊，這些變量可以被改變，下面給出了最常用的一些變量。

ARGC               指令行參數個數
ARGV               指令行參數排列
ENVIRON            支援隊列中系統環境變量的使用
FILENAME           awk浏覽的檔案名
FNR                浏覽檔案的記錄數
FS                 設定輸入域分隔符，等價于指令行 -F選項
NF                 浏覽記錄的域的個數
NR                 已讀的記錄數
OFS                輸出域分隔符
ORS                輸出記錄分隔符
RS                 控制記錄分隔符

此外,$0變量是指整條記錄。$1表示目前行的第一個域,$2表示目前行的第二個域,......以此類推。

統計/etc/passwd:檔案名，每行的行号，每行的列數，對應的完整行内容:

#awk  -F ':'  '{print "filename:" FILENAME ",linenumber:" NR ",columns:" NF ",linecontent:"$0}' /etc/passwd
filename:/etc/passwd,linenumber:1,columns:7,linecontent:root:x:0:0:root:/root:/bin/bash
filename:/etc/passwd,linenumber:2,columns:7,linecontent:daemon:x:1:1:daemon:/usr/sbin:/bin/sh
filename:/etc/passwd,linenumber:3,columns:7,linecontent:bin:x:2:2:bin:/bin:/bin/sh
filename:/etc/passwd,linenumber:4,columns:7,linecontent:sys:x:3:3:sys:/dev:/bin/sh

　使用printf替代print,可以讓代碼更加簡潔，易讀

awk  -F ':'  '{printf("filename:%10s,linenumber:%s,columns:%s,linecontent:%s\n",FILENAME,NR,NF,$0)}' /etc/passwd

print和printf

awk中同時提供了print和printf兩種列印輸出的函數。

其中print函數的參數可以是變量、數值或者字元串。字元串必須用雙引号引用，參數用逗号分隔。如果沒有逗号，參數就串聯在一起而無法區分。這裡，逗号的作用與輸出檔案的分隔符的作用是一樣的，隻是後者是空格而已。

printf函數，其用法和c語言中printf基本相似,可以格式化字元串,輸出複雜時，printf更加好用，代碼更易懂。

awk程式設計

變量和指派

除了awk的内置變量，awk還可以自定義變量。

下面統計/etc/passwd的賬戶人數

awk '{count++;print $0;} END{print "user count is ", count}' /etc/passwd
root:x:0:0:root:/root:/bin/bash
......
user count is  40

count是自定義變量。之前的action{}裡都是隻有一個print,其實print隻是一個語句，而action{}可以有多個語句，以;号隔開。

這裡沒有初始化count，雖然預設是0，但是妥當的做法還是初始化為0:

awk 'BEGIN {count=0;print "[start]user count is ", count} {count=count+1;print $0;} END{print "[end]user count is ", count}' /etc/passwd
[start]user count is  0
root:x:0:0:root:/root:/bin/bash
...
[end]user count is  40

　　統計某個檔案夾下的檔案占用的位元組數

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print "[end]size is ", size}'
[end]size is  8657198

　　如果以M為機關顯示:

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print "[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.25889 M

注意，統計不包括檔案夾的子目錄。

條件語句

awk中的條件語句是從C語言中借鑒來的，見如下聲明方式：

if (expression) {
    statement;
    statement;
    ... ...
}

if (expression) {
    statement;
} else {
    statement2;
}

if (expression) {
    statement1;
} else if (expression1) {
    statement2;
} else {
    statement3;
}

　　統計某個檔案夾下的檔案占用的位元組數,過濾4096大小的檔案(一般都是檔案夾):

ls -l |awk 'BEGIN {size=0;print "[start]size is ", size} {if($5!=4096){size=size+$5;}} END{print "[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.22339 M

循環語句

awk中的循環語句同樣借鑒于C語言，支援while、do/while、for、break、continue，這些關鍵字的語義和C語言中的語義完全相同。

數組

因為awk中數組的下标可以是數字和字母，數組的下标通常被稱為關鍵字(key)。值和關鍵字都存儲在内部的一張針對key/value應用hash的表格裡。由于hash不是順序存儲，是以在顯示數組内容時會發現，它們并不是按照你預料的順序顯示出來的。數組和變量一樣，都是在使用時自動建立的，awk 也同樣會自動判斷其存儲的是數字還是字元串。一般而言，awk中的數組用來從記錄中收集資訊，可以用于計算總和、統計單詞以及跟蹤模闆被比對的次數等等。

顯示/etc/passwd的賬戶

awk -F ':' 'BEGIN {count=0;} {name[count] = $1;count++;}; END{for (i = 0; i < NR; i++) print i, name[i]}' /etc/passwd
0 root
1 daemon
2 bin
3 sys
4 sync
5 games
......

　　這裡使用for循環周遊數組

awk程式設計的内容極多，這裡隻羅列簡單常用的用法，更多請參考 http://www.gnu.org/software/gawk/manual/gawk.html

原文連結：http://www.cnblogs.com/ggjucheng/archive/2013/01/13/2858470.html